10 POKE53281,11:POKE53280,15:POKE646,13
100 INPUT"[147]ANLEITUNG ? J[157][157][157]";Z$:IFLEFT$(Z$,1)<>"J"GOTO200
110 PRINT"[147]JEDER VON UNS HAT 5 SCHIFFE, DIE"
120 PRINT"DER JEWEILS ANDERE NICHT SEHEN KANN."
130 PRINT"WIR SCHIESSEN ABWECHSELND AUF EINE"
140 PRINT"KOORDINATE. - DANEBEN= '[215]', TREFFER= ' [146]'"
150 PRINT"DU MUSST VERSUCHEN, MEINE SCHIFFE ZU"
160 PRINT"VERSENKEN, BEVOR ICH DEINE VERSENKE."
170 PRINT"ZUERST MUSST DU DIE LAGE EINGEBEN, Z.B. 'LAENGE 3' MIT 'E4-E6'."
180 PRINT"VIEL GLUECK!   TASTE DRUECKEN !!"
190 GETZ$:IFZ$=""GOTO190
200 DIM B(9,9,1),N$(4),L(4),H(4,1):R=TI
210 PRINT"[147]BATTLESHIPS    J. BUTTERFIELD "
230 DATA CARRIER,BATTLESHIP,CRUISER,SUBMARINE,"PT BOAT"
240 DATA 5,5,4,3,2
250 FOR J=0 TO 4:READ N$(J):NEXT J:FORJ=0TO4:READL(J):NEXTJ
260 R=R/1000:R1=RND(-R):IFR>1GOTO260
280 PRINT "  MY BOARD   YOUR BOARD"
290 Z=0:Z$="[176][178][178][178][178][178][178][178][178][174]":GOSUB 1100
300 Z$="[171][219][219][219][219][219][219][219][219][179]":FORZ=1TO8:GOSUB1100:NEXT Z
310 Z$="[173][177][177][177][177][177][177][177][177][189]":GOSUB 1100
320 Z$=""
330 E$=Z$+"                                        [145]"
340 PRINT"^^^^^^^^^^":PRINT"ABCDEFGHIJ"
350 PRINTZ$;"INPUT YOUR SHIPS (I WON'T PEEK)..."
360 FORJ=1TO1000:NEXTJ:PRINTE$;"GIVE END CO-ORDINATES FOR EACH SHIP..."
370 FORL=0TO1:FORJ=0TO9:FORK=0TO9:B(J,K,L)=0:NEXTK,J,L
380 FORL=0TO1:FORJ=0TO4:H(J,L)=0:NEXTJ,L
390 FORC=0TO4
400 PRINTE$;N$(C);" (LAENGE";L(C);")";:INPUTY$:GOSUB1110:IFE=1GOTO400
410 X1=X:Y1=Y:GOSUB1120:IFE=1GOTO400
420 L=L(C):IFX<>X1ANDABS(X-X1)<>L-1GOTO400
430 IFY<>Y1ANDABS(Y-Y1)<>L-1GOTO400
440 IFY=Y1ANDX=X1GOTO400
450 Y2=SGN(Y1-Y):X2=SGN(X1-X):Y3=Y:X3=X
460 FORJ=1TOL-1:IFB(X3,Y3,0)<>0GOTO400
470 IFX2*Y2<>0THENIFB(X3+X2,Y3,0)=B(X3,Y3+Y2,0)THENIFB(X3,Y3+Y2,0)<>0GOTO400
480 X3=X3+X2:Y3=Y3+Y2:NEXTJ
490 IFB(X3,Y3,0)<>0GOTO400
500 Y$="[209]":FORJ=1TOL:B(X,Y,0)=C+1:GOSUB1160:X=X+X2:Y=Y+Y2:NEXTJ,C
510 PRINTE$;"NOW I AM READY..":S=0:H9=0
520 FORC=0TO4:L=L(C)
530 D=INT(RND(1)*4):X1=L-1:Y1=L-1
540 IFD=2THENX1=0
550 IFD=0THENY1=0
560 X=INT(RND(1)*(10-X1)):IFD=3THENX=X+X1
570 Y=INT(RND(1)*(10-Y1)):Y3=Y:X3=X:X2=SGN(2-D):Y2=SGN(Y1)
580 FORJ=1TOL-1:IFB(X3,Y3,1)<>0GOTO530
590 IFX2*Y2<>0THENIFB(X3+X2,Y3,1)=B(X3,Y3+Y2,1)THENIFB(X3,Y3+Y2,1)<>0GOTO530
600 X3=X3+X2:Y3=Y3+Y2:NEXTJ
610 IFB(X3,Y3,1)<>0GOTO530
620 FORJ=1TOL:B(X,Y,1)=C+1:X=X+X2:Y=Y+Y2:NEXTJ,C
630 PRINTE$;
640 INPUT": YOUR SHOT";Y$
650 GOSUB 1110:IFE=1GOTO630
660 B=B(X,Y,1):IFB>9GOTO630
670 B(X,Y,1)=B+10:Y$="[215]":IFB=0GOTO710
680 Y$=" ":H(B-1,1)=H(B-1,1)+1:IFH(B-1,1)<L(B-1)GOTO710
690 PRINTE$;N$(B-1);" SUNK":FORC=1TO2000:NEXTC:FORC=0TO4:IFH(C,1)<L(C)GOTO710
700 NEXTC:GOTO1210
710 GOSUB1170
720 ONSGOTO780,860
730 X=INT(RND(1)*10):Y=INT(RND(1)*10)
740 B=B(X,Y,0):IFB<9GOTO 920
750 X=X+3:IFX<10GOTO740
760 X=X-10:Y=Y+1:IFY<10GOTO740
770 Y=Y-10:GOTO740
780 X1=X9-D:X2=X9+D:Y1=Y9-D:Y2=Y9+D
790 IFX1<0THENX1=0
800 IFY1<0THENY1=0
810 IFX2>9THENX2=9
820 IFY2>9THENY2=9
830 FORX=X1TOX2:FORY=Y1TOY2
840 B=B(X,Y,0):IFB<9GOTO 920
850 NEXTY,X:D=D+1:GOTO780
860 X=X9:Y=Y9
870 X=X+X8:Y=Y+Y8:IFX<0ORX>9ORY<0ORY>9GOTO900
880 B=B(X,Y,0):IFB<9GOTO 920
890 B=B-10:IFB>0GOTO870
900 IFS1=1THENS=1:GOTO780
910 S1=1:X8=-X8:Y8=-Y8:GOTO860
920 B(X,Y,0)=B+10:Y$="[215]":H7=0:H8=SGN(B):H9=H9+H8:X$="MISS":IFB=0GOTO 950
930 B=B-1:Y$=" ":X$="HIT":H(B,0)=H(B,0)+1:IFH(B,0)<L(B)GOTO 950
940 H7=1:H9=H9-L(B):X$="SINK "+N$(B)
950 GOSUB1160:PRINTE$;"I ";X$;" AT ";CHR$(X+65);CHR$(Y+48);:FORJ=1TO1000:NEXTJ
960 FORJ=0TO4:IFH(J,0)<L(J)GOTO 980
970 NEXTJ:GOTO1220
980 ONSGOTO1010,1060
990 IFH8=1THENS=1:D=1:X9=X:Y9=Y
1000 GOTO640
1010 IFH9=0THENS=0:GOTO640
1020 IFH8=0GOTO640
1030 X8=X-X9:Y8=Y-Y9:S1=0
1040 IFX8=SGN(X8)ANDY8=SGN(Y8)THENS=2
1050 GOTO640
1060 IFH7=0GOTO640
1070 S=1
1080 IFH9=0THENS=0
1090 GOTO640
1100 PRINTZ$;"_";CHR$(Z+48);" ";Z$:RETURN
1110 P=1:E=0
1120 FOR Z=PTOLEN(Y$)-1:X=ASC(MID$(Y$,Z))-65:IFX>=0ANDX<=9GOTO1140
1130 NEXTZ:E=1:RETURN
1140 FOR P=ZTOLEN(Y$):Y=ASC(MID$(Y$,P))-48:IFY>=0ANDY<=9THENRETURN
1150 NEXTP:GOTO1130
1160 PRINT"";TAB(13);:GOTO1180
1170 PRINT"";
1180 FORQ=1TOY+2:PRINT"";:NEXT Q
1190 FORQ=1TOX+1:PRINT"";:NEXT Q
1200 PRINT"[157]";Y$:RETURN
1210 GOSUB1170:PRINTE$;"YOU WIN":GOTO1270
1220 PRINT:PRINT"I WIN -I'LL SHOW MY HIDDEN SHIPS"
1230 FORX=0TO9:FORY=0TO9
1240 B=B(X,Y,1):IFB=0ORB>9GOTO1260
1250 Y$="[209]":GOSUB1170
1260 NEXTY:NEXTX
1270 PRINTZ$;" ANOTHER GAME";
1280 INPUTY$:IFLEFT$(Y$,1)<>"N"GOTO270